#define scr_pause
//scr_pause(unpause_object,dont_freeze_me,string_executed)
//by IsmAvatar
//freezes all objects, but continues to display them

//unpause_object is basically the main object that stays active during
 //this freeze session. It could be a menu, etc. Make sure to
 //execute scr_unpause somewhere (preferrably in the unpause object)
 //otherwise, the objects won't unpause. To create no object, use -1
//dont_freeze_me should be true if you don't want this object to be frozen
 //in the process. If it's ok to freeze it, just leave this argument out,
 //or set it to false
//string_executed is what you would like to do after freezing everything
 //creation of an object will cause the object to not be frozen
 //you can also unfreeze objects you don't want frozen
 //you can also perform various actions upon unpause_object
 //leave this argument out (or false) if you don't want anything executed

//please note, an object named "obj_freeze" must already exist
//everything for this object should be cleared

//These scripts have not been tested, so if you find any problems
//PLEASE report them to IsmAvatar, admin@IsmAvatar.tk


with all {
 zz = instance_create(x,y,obj_freeze)
 zz.sprite_index = sprite_index
 zz.image_single = image_single
 zz.image_speed = 0
 zz.image_index = image_index
 zz.visible = visible
 zz.depth = depth
 zz.mytoken = id
}
instance_deactivate_all(true)
if argument0 != -1 { unpause_object = instance_create(0,0,argument0) }
if string(argument2) != "0" { execute_string(argument2) }
if argument1 != 1 { instance_deactivate_object(id) }

#define scr_dontpause
//scr_dontfreeze(target)
//by IsmAvatar
//Unpauses target that you didn't want frozen
//Should be executed either in the scr_pause's string_executed
//or in the create event of unpause_object

instance_activate_object(argument0)
with (argument0.zz) { instance_destroy() }


#define scr_unpause
//scr_unpause()
//by IsmAvatar
//Unpauses all objects paused by scr_pause
//No arguments


with (obj_freeze) { instance_destroy() }
instance_activate_all()